SILENT KILLERPanel

Current Path: > > usr > > share > awk

Operation   : Linux premium131.web-hosting.com 4.18.0-553.44.1.lve.el8.x86_64 #1 SMP Thu Mar 13 14:29:12 UTC 2025 x86_64
Software     : Apache
Server IP    : 162.0.232.56 | Your IP: 216.73.216.111
Domains      : 1034 Domain(s)
Permission   : [ 0755 ]

Files and Folders in: //usr//share/awk

NameTypeSizeLast ModifiedActions
assert.awk File 383 bytes February 25 2018 17:17:35.
bits2str.awk File 334 bytes February 25 2018 17:17:35.
cliff_rand.awk File 307 bytes February 25 2018 17:17:35.
ctime.awk File 234 bytes February 25 2018 17:17:35.
ftrans.awk File 315 bytes February 25 2018 17:17:35.
getopt.awk File 2202 bytes February 25 2018 17:17:35.
gettime.awk File 2491 bytes February 25 2018 17:17:35.
group.awk File 1765 bytes April 18 2022 15:55:53.
have_mpfr.awk File 221 bytes February 25 2018 17:17:35.
inplace.awk File 1996 bytes February 25 2018 17:17:35.
intdiv0.awk File 462 bytes February 25 2018 17:17:35.
join.awk File 378 bytes February 25 2018 17:17:35.
libintl.awk File 238 bytes February 25 2018 17:17:35.
noassign.awk File 422 bytes February 25 2018 17:17:35.
ord.awk File 937 bytes February 25 2018 17:17:35.
passwd.awk File 1199 bytes April 18 2022 15:55:53.
processarray.awk File 355 bytes February 25 2018 17:17:35.
quicksort.awk File 1031 bytes February 25 2018 17:17:35.
readable.awk File 489 bytes February 25 2018 17:17:35.
readfile.awk File 267 bytes February 25 2018 17:17:35.
rewind.awk File 404 bytes February 25 2018 17:17:35.
round.awk File 661 bytes February 25 2018 17:17:35.
shellquote.awk File 472 bytes February 25 2018 17:17:35.
strtonum.awk File 1454 bytes February 25 2018 17:17:35.
walkarray.awk File 214 bytes February 25 2018 17:17:35.
zerofile.awk File 424 bytes February 25 2018 17:17:35.

Reading File: //usr//share/awk/getopt.awk

# getopt.awk --- Do C library getopt(3) function in awk
#
# Arnold Robbins, arnold@skeeve.com, Public Domain
#
# Initial version: March, 1991
# Revised: May, 1993

# External variables:
#    Optind -- index in ARGV of first nonoption argument
#    Optarg -- string value of argument to current option
#    Opterr -- if nonzero, print our own diagnostic
#    Optopt -- current option letter

# Returns:
#    -1     at end of options
#    "?"    for unrecognized option
#    <c>    a character representing the current option

# Private Data:
#    _opti  -- index in multiflag option, e.g., -abc
function getopt(argc, argv, options,    thisopt, i)
{
    if (length(options) == 0)    # no options given
        return -1

    if (argv[Optind] == "--") {  # all done
        Optind++
        _opti = 0
        return -1
    } else if (argv[Optind] !~ /^-[^:[:space:]]/) {
        _opti = 0
        return -1
    }
    if (_opti == 0)
        _opti = 2
    thisopt = substr(argv[Optind], _opti, 1)
    Optopt = thisopt
    i = index(options, thisopt)
    if (i == 0) {
        if (Opterr)
            printf("%c -- invalid option\n", thisopt) > "/dev/stderr"
        if (_opti >= length(argv[Optind])) {
            Optind++
            _opti = 0
        } else
            _opti++
        return "?"
    }
    if (substr(options, i + 1, 1) == ":") {
        # get option argument
        if (length(substr(argv[Optind], _opti + 1)) > 0)
            Optarg = substr(argv[Optind], _opti + 1)
        else
            Optarg = argv[++Optind]
        _opti = 0
    } else
        Optarg = ""
    if (_opti == 0 || _opti >= length(argv[Optind])) {
        Optind++
        _opti = 0
    } else
        _opti++
    return thisopt
}
BEGIN {
    Opterr = 1    # default is to diagnose
    Optind = 1    # skip ARGV[0]

    # test program
    if (_getopt_test) {
        while ((_go_c = getopt(ARGC, ARGV, "ab:cd")) != -1)
            printf("c = <%c>, Optarg = <%s>\n",
                                       _go_c, Optarg)
        printf("non-option arguments:\n")
        for (; Optind < ARGC; Optind++)
            printf("\tARGV[%d] = <%s>\n",
                                    Optind, ARGV[Optind])
    }
}

SILENT KILLER Tool